Skip to main content

Assigning the open address list permission on a Address list with ADSI

Somebody asked me what the ACE access mask is for Open Address List on an address list object in Exchange. I thought this should be a relatively straight forward thing to find but apparently not although most of the other ADSI permission enums are documented and used a fair bit this one seems to be a little neglected. There are some hidden gems in the Exchange SDK but unless you know what you looking at its easy to look straight over them. The SDK gives us a create GAL sample using ADSI . Within this sample the following line gives the accessmask and all the right setting needed to add an “open address list ACE”

AddAce objCopyDACL, szUserGroup + "@" + szDomain, 256, 5, 2, 1, "{A1990816-4298-11D1-ADE2-00C04FD8D5CD}", 0

Unfortunately they haven’t used a constant in this script to tell you what the 256 access mask means but there is an easy way I use to work this out. Which is basically add a unique user to an address list and give it only the “Open address list” right and then use the following little script to output what the ACE entries are for that object. Then all I need to do is look at what access mask gets assigned to the ACE for the unique user I added. The script to do is a simple ACE list example which looks like. This is a modified version of the script from this kb

sUserADsPath = "LDAP://DN-of-Addresslist"
Set objadlist = GetObject(sUserADsPath)
Set oSecurityDescriptor = objadlist.Get("ntSecurityDescriptor")
Set dacl = oSecurityDescriptor.DiscretionaryAcl
Set ace = CreateObject("AccessControlEntry")
wscript.echo "Here are the existing ACEs in the DACL:"
For Each ace In dacl
' Display all the properties of the ACEs using the IADsAccessControlEntry interface.
wscript.echo ace.Trustee & ", " & ace.AccessMask & ", " & ace.AceType & ", " & ace.AceFlags & ", " & ace.Flags & ", " & ace.ObjectType & ", " & ace.InheritedObjectType
Next
wscript.echo "Done viewing descriptor"

So to add a user with the open address list right to a existing address list all you need to do is combine bits from the create GAL sample I mentioned above with the addace and reorder ACE function in the Exchange SDK. The result of such a combination looks something like this. I’ve placed a download copy of the scripts here.

strDNofADdresslist = "LDAP://DN-of-Addresslist"
Set objgal = GetObject(strDNofADdresslist)
Set objSecurityDescriptor = objgal.Get("ntSecurityDescriptor")
iCurrentControl = objSecurityDescriptor.Control
objSecurityDescriptor.Control = iCurrentControl Or SE_DACL_PROTECTED
Set objParentSD = objgal.Get("ntSecurityDescriptor")
Set objParentDACL = objParentSD.DiscretionaryAcl
Set objCopyDACL = objParentDACL.CopyAccessList()

AddAce objCopyDACL, "domain\userID", 256, 5, 2, 1, "{A1990816-4298-11D1-ADE2-00C04FD8D5CD}", 0

Set objNewDACL = ReorderACL(objCopyDACL)
objSecurityDescriptor.DiscretionaryAcl = objNewDACL
objgal.Put "ntSecurityDescriptor", objSecurityDescriptor
objgal.SetInfo

Function AddAce( objDacl, _
szTrusteeName, _
gAccessMask, _
gAceType, _
gAceFlags, _
gFlags, _
gObjectType, _
gInheritedObjectType)
Set Ace1 = CreateObject("AccessControlEntry")
Ace1.AccessMask = gAccessMask
Ace1.AceType = gAceType
Ace1.AceFlags = gAceFlags
Ace1.Flags = gFlags
Ace1.Trustee = szTrusteeName
If CStr(gObjectType) <> "0" Then
Ace1.ObjectType = gObjectType
End If
If CStr(gInheritedObjectType) <> "0" Then
Ace1.InheritedObjectType = gInheritedObjectType
End If
objDacl.AddAce Ace1
Set Ace1 = Nothing
wscript.echo "Ace added"
End Function

Function ReorderACL(objDacl)
' Set Constants.
Const ADS_ACETYPE_ACCESS_DENIED = &H1
Const ADS_ACETYPE_ACCESS_DENIED_OBJECT = &H6
Const ADS_ACETYPE_ACCESS_ALLOWED = &H0
Const ADS_ACETYPE_ACCESS_ALLOWED_OBJECT = &H5
Const ADS_ACEFLAG_INHERITED_ACE = &H10
Set objSD = CreateObject("SecurityDescriptor")
Set newDACL = CreateObject("AccessControlList")
Set ImpDenyDacl = CreateObject("AccessControlList")
Set ImpDenyObjectDacl = CreateObject("AccessControlList")
Set ImpAllowDacl = CreateObject("AccessControlList")
Set ImpAllowObjectDacl = CreateObject("AccessControlList")

For Each ace In objDacl
Select Case ace.AceType
Case ADS_ACETYPE_ACCESS_DENIED
ImpDenyDacl.AddAce ace
Case ADS_ACETYPE_ACCESS_DENIED_OBJECT
ImpDenyObjectDacl.AddAce ace
Case ADS_ACETYPE_ACCESS_ALLOWED
ImpAllowDacl.AddAce ace
Case ADS_ACETYPE_ACCESS_ALLOWED_OBJECT
ImpAllowObjectDacl.AddAce ace
Case Else
wscript.echo "bad ACE"
End Select
Next
' Combine the ACEs in the Proper Order
' Implicit Deny.
For Each ace In ImpDenyDacl
newDACL.AddAce ace
Next
' Implicit Deny Object.
For Each ace In ImpDenyObjectDacl
newDACL.AddAce ace
Next
' Implicit Allow.
For Each ace In ImpAllowDacl
newDACL.AddAce ace
Next
' Implicit Allow Object.
For Each ace In ImpAllowObjectDacl
newDACL.AddAce ace
Next
newDACL.AclRevision = objDacl.AclRevision
Set ReorderACL = newDACL
Set newDACL = Nothing
Set ImpAllowObjectDacl = Nothing
Set ImpAllowDacl = Nothing
Set ImpDenyObjectDacl = Nothing
Set ImpDenyDacl = Nothing
Set objSD = Nothing
wscript.echo "DACL Reordered"
End Function

Popular posts from this blog

Testing and Sending email via SMTP using Opportunistic TLS and oAuth in Office365 with PowerShell

As well as EWS and Remote PowerShell (RPS) other mail protocols POP3, IMAP and SMTP have had OAuth authentication enabled in Exchange Online (Official announcement here ). A while ago I created  this script that used Opportunistic TLS to perform a Telnet style test against a SMTP server using SMTP AUTH. Now that oAuth authentication has been enabled in office365 I've updated this script to be able to use oAuth instead of SMTP Auth to test against Office365. I've also included a function to actually send a Message. Token Acquisition  To Send a Mail using oAuth you first need to get an Access token from Azure AD there are plenty of ways of doing this in PowerShell. You could use a library like MSAL or ADAL (just google your favoured method) or use a library less approach which I've included with this script . Whatever way you do this you need to make sure that your application registration  https://docs.microsoft.com/en-us/azure/active-directory/develop/quickstart-register-
Read more

The MailboxConcurrency limit and using Batching in the Microsoft Graph API

If your getting an error such as Application is over its MailboxConcurrency limit while using the Microsoft Graph API this post may help you understand why. Background   The Mailbox  concurrency limit when your using the Graph API is 4 as per https://docs.microsoft.com/en-us/graph/throttling#outlook-service-limits . This is evaluated for each app ID and mailbox combination so this means you can have different apps running under the same credentials and the poor behavior of one won't cause the other to be throttled. If you compared that to EWS you could have up to 27 concurrent connections but they are shared across all apps on a first come first served basis. Batching Batching in the Graph API is a way of combining multiple requests into a single HTTP request. Batching in the Exchange Mail API's EWS and MAPI has been around for a long time and its common, for email Apps to process large numbers of smaller items for a variety of reasons.  Batching in the Graph is limited to a m
Read more

How to test SMTP using Opportunistic TLS with Powershell and grab the public certificate a SMTP server is using

Most email services these day employ Opportunistic TLS when trying to send Messages which means that wherever possible the Messages will be encrypted rather then the plain text legacy of SMTP.  This method was defined in RFC 3207 "SMTP Service Extension for Secure SMTP over Transport Layer Security" and  there's a quite a good explanation of Opportunistic TLS on Wikipedia  https://en.wikipedia.org/wiki/Opportunistic_TLS .  This is used for both Server to Server (eg MTA to MTA) and Client to server (Eg a Message client like Outlook which acts as a MSA) the later being generally Authenticated. Basically it allows you to have a normal plain text SMTP conversation that is then upgraded to TLS using the STARTTLS verb. Not all servers will support this verb so if its not supported then a message is just sent as Plain text. TLS relies on PKI certificates and the administrative issue s that come around certificate management like expired certificates which is why I wrote th
Read more
All sample scripts and source code is provided by for illustrative purposes only. All examples are untested in different environments and therefore, I cannot guarantee or imply reliability, serviceability, or function of these programs.

All code contained herein is provided to you "AS IS" without any warranties of any kind. The implied warranties of non-infringement, merchantability and fitness for a particular purpose are expressly disclaimed.