Skip to main content

Creating one off SCL Rules with the Rule.dll

When using the IMF to do spam filtering you do get the occasional user where the SCL store threshold is set a little too high. Eg if you have the store threshold set to 6 and one user is getting a lot of SPAM that is getting a SCL of 5 having a one-off type trick to push these emails into the junk email folder can come in handy.

One way to do this is using the old Rule.dll COM component to create a server side rule in the inbox. Rule.dll has been around since Exchange 5.5 and because its mapi based it still works as it did back Exchange 5.5. There’s a great reference page with a lot samples on MSDN here

Some fast hard facts about using the rule.dll, Rules created using the rule.dll can’t be seen, deleted or modified using Outlook. And you still need to watch out for the 32 KB rules limit on a folder. There is a copy of the rule.dll included in one of the samples on CDOlive http://www.cdolive.net/download/ruleasp.zip or there should be a copy in the Platform SDK.

So to create a Rule base on the SCL value of an email you need to look at using the (PR_CONTENT_FILTER_SCL &H40760003) mapi property. So what the script does is first logs on the target mailbox finds the junk email folder by going though all the top level folders in the mailbox. Then creates a rule with a PropertyCondition so that if any mail is recived with a SCL of 5 then it gets moved into the junk email folder.

I’ve posted up a download copy of the code here
The script looks like


const REL_EQ = 7
Const ACTION_MOVE = 1
const CdoPR_CONTENT_FILTER_SCL = &H40760003
const SCL_VAL = 5

servername = "servername"
mailboxname = "mailboxalias"

Set objSession = CreateObject("MAPI.Session")

objSession.Logon "","",false,true,true,true,servername & vbLF & mailboxname
Set objRules = CreateObject("MSExchange.Rules")
objRules.Folder = objSession.Inbox
Set objInbox = objSession.Inbox

Set CdoInfoStore = objSession.GetInfoStore
Set CdoFolderRoot = CdoInfoStore.RootFolder
Set CdoFolders = CdoFolderRoot.Folders

bFound = False
Set CdoFolder = CdoFolders.GetFirst
Do While (Not bFound) And Not (CdoFolder Is Nothing)
If CdoFolder.Name = "Junk E-mail" Then
bFound = True
Else
Set CdoFolder = CdoFolders.GetNext
End If
Loop
Set ActionFolder = CdoFolder

Set importPropVal = CreateObject("MSExchange.PropertyValue")
importPropVal.Tag = CdoPR_CONTENT_FILTER_SCL
importPropVal.Value = SCL_VAL

Set importPropCond = CreateObject("MSExchange.PropertyCondition")
importPropCond.PropertyTag = CdoPR_CONTENT_FILTER_SCL
importPropCond.Operator = REL_EQ
importPropCond.Value = importPropVal

' Create action
Set objAction = CreateObject("MSExchange.Action")
objAction.ActionType = ACTION_MOVE
objAction.Arg = ActionFolder

' Create new rule
Set objRule = CreateObject("MSExchange.Rule")
objRule.Name = "SCL VAL Move"

' Add action and assign condition
objRule.Actions.Add , objAction
objRule.Condition = importPropCond

' Add rule and update
objRules.Add , objRule
objRules.Update

' Log off and cleanup
objSession.Logoff

Set objRules = Nothing
Set objSession = Nothing
Set importProp = Nothing
Set importPropVal = Nothing
Set objAction = Nothing
Set objRule = Nothing

Popular posts from this blog

Exporting and Uploading Mailbox Items using Exchange Web Services using the new ExportItems and UploadItems operations in Exchange 2010 SP1

Two new EWS Operations ExportItems and UploadItems where introduced in Exchange 2010 SP1 that allowed you to do a number of useful things that where previously not possible using Exchange Web Services. Any object that Exchange stores is basically a collection of properties for example a message object is a collection of Message properties, Recipient properties and Attachment properties with a few meta properties that describe the underlying storage thrown in. Normally when using EWS you can access these properties in a number of a ways eg one example is using the strongly type objects such as emailmessage that presents the underlying properties in an intuitive way that's easy to use. Another way is using Extended Properties to access the underlying properties directly. However previously in EWS there was no method to access every property of a message hence there is no way to export or import an item and maintain full fidelity of every property on that item (you could export the...
Read more

Sending a Message in Exchange Online via REST from an Arduino MKR1000

This is part 2 of my MKR1000 article, in this previous post  I looked at sending a Message via EWS using Basic Authentication.  In this Post I'll look at using the new Outlook REST API  which requires using OAuth authentication to get an Access Token. The prerequisites for this sketch are the same as in the other post with the addition of the ArduinoJson library  https://github.com/bblanchon/ArduinoJson  which is used to parse the Authentication Results to extract the Access Token. Also the SSL certificates for the login.windows.net  and outlook.office365.com need to be uploaded to the devices using the wifi101 Firmware updater. To use Token Authentication you need to register an Application in Azure https://msdn.microsoft.com/en-us/office/office365/howto/add-common-consent-manually  with the Mail.Send permission. The application should be a Native Client app that use the Out of Band Callback urn:ietf:wg:oauth:2.0:oob. You ...
Read more

The MailboxConcurrency limit and using Batching in the Microsoft Graph API

If your getting an error such as Application is over its MailboxConcurrency limit while using the Microsoft Graph API this post may help you understand why. Background   The Mailbox  concurrency limit when your using the Graph API is 4 as per https://docs.microsoft.com/en-us/graph/throttling#outlook-service-limits . This is evaluated for each app ID and mailbox combination so this means you can have different apps running under the same credentials and the poor behavior of one won't cause the other to be throttled. If you compared that to EWS you could have up to 27 concurrent connections but they are shared across all apps on a first come first served basis. Batching Batching in the Graph API is a way of combining multiple requests into a single HTTP request. Batching in the Exchange Mail API's EWS and MAPI has been around for a long time and its common, for email Apps to process large numbers of smaller items for a variety of reasons.  Batching in the Gr...
Read more
All sample scripts and source code is provided by for illustrative purposes only. All examples are untested in different environments and therefore, I cannot guarantee or imply reliability, serviceability, or function of these programs.

All code contained herein is provided to you "AS IS" without any warranties of any kind. The implied warranties of non-infringement, merchantability and fitness for a particular purpose are expressly disclaimed.