Skip to main content

IMF message tracking ID's and Spam Report script

If you have Message Tracking Logging enabled on your server then Exchange records details about the message transfer process into the message tracking logs which can then be searched via Exchange System Manager - Message Tracking Center. A full list of Tacking ID and descriptions for Exchange 2003 can be found in the Exchange FAQ . With the release of the IMF there are now some new Tracking ID's that get logged when the IMF takes action on a message at the gateway level. The ID's look like this

1039 SMTP:Message Deleted by Intelligent Message Filtering
1040 SMTP:Message Rejected by Intelligent Message Filtering
1041 SMTP:Messgae Archived by Intelligent Message Filtering

Depending on how you have your Gateway actions set you will get 1 or 2 of theses events logged when a gateway action is performed , Eg if you have your gateway action set to archive you get a 1041 logged and then a 1039 logged.
Apart from System Manager the Message tracking logs can be accessed via WMI using the Exchange_MessageTrackingEntry Class which is part of the ROOT\MicrosoftExchangeV2 Namespace.

As part of my daily Sys-Admin duties I wanted to be able to check what emails the IMF took action on over the past day, so what I came up with is a script that uses a WMI WQL query of all the 1039 events for the past day, puts the results in a HTML table and then emails me. The script I used is below - There are some time conversion routines to convert UTC times to local and also construct the time variable format required for WQL. The only other thing of note is that I have subject logging enable on my server which the script expects. To use it I just created a scheduled task that runs the script once a day in the morning.

Its had about a day of testing (the joys of blogging) and worked okay last night Enjoy.


SpamReport = "<table border=""1"" cellpadding=""0"" cellspacing=""0"" width=""100%"">" & vbcrlf
SpamReport = SpamReport & "<table border=""1"" cellpadding=""0"" cellspacing=""0"" width=""100%"">" & vbcrlf
SpamReport = SpamReport & " <tr>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">Time</td>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">Ip</td>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">From</td>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">Sent-TO</td>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">Subject</td>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">Size</td>" & vbcrlf
SpamReport = SpamReport & "</tr>" & vbcrlf
strComputer = "."
set shell = createobject("wscript.shell")
strValueName = "HKLM\SYSTEM\CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias"
minTimeOffset = shell.regread(strValueName)
toffset = datediff("h",DateAdd("n", minTimeOffset, now()),now())
dtListFrom = DateAdd("n", minTimeOffset, now())
dtListFrom = DateAdd("d",-1,dtListFrom)
strStartDateTime = year(dtListFrom)
if (Month(dtListFrom) < 10) then strStartDateTime = strStartDateTime & "0"
strStartDateTime = strStartDateTime & Month(dtListFrom)
if (Day(dtListFrom) < 10) then strStartDateTime = strStartDateTime & "0"
strStartDateTime = strStartDateTime & Day(dtListFrom)
if (Hour(dtListFrom) < 10) then strStartDateTime = strStartDateTime & "0"
strStartDateTime = strStartDateTime & Hour(dtListFrom)
if (Minute(dtListFrom) < 10) then strStartDateTime = strStartDateTime & "0"
strStartDateTime = strStartDateTime & Minute(dtListFrom)
if (Second(dtListFrom) < 10) then strStartDateTime = strStartDateTime & "0"
strStartDateTime = strStartDateTime & Second(dtListFrom) & ".000000+000"
Set objWMIService = Getobject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\MicrosoftExchangeV2")
qstr = "Select * FROM Exchange_MessageTrackingEntry where entrytype = '1039' and OriginationTime > '" & strStartDateTime & "'"
Set colLoggedEvents = objWMIService.ExecQuery(qstr,,48)
spamcount = 0
spambytes = 0
For Each objEvent in colLoggedEvents
for i = 1 to objEvent.RecipientCount
OTime = objEvent.OriginationTime
odate = dateadd("h",toffset,cdate(DateSerial(Left(OTime, 4), Mid(OTime, 5, 2), Mid(OTime, 7, 2)) _
& " " & timeserial(Mid(OTime, 9, 2),Mid(OTime, 11, 2),Mid(OTime,13, 2))))
SpamReport = SpamReport & " <tr>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">" & formatdatetime(odate,4) & "</td>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">" & objEvent.clientip & "</td>"& vbcrlf
SpamReport = SpamReport & "<td align=""center"">" & objEvent.SenderAddress & "</td>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">" & objEvent.RecipientAddress((i-1)) & "</td>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">" & objEvent.Subject & "</td>" & vbcrlf
SpamReport = SpamReport & "<td align=""center"">" & objEvent.size & "</td>" & vbcrlf
SpamReport = SpamReport & "</tr>" & vbcrlf
spamcount = spamcount + 1
spambytes = spambytes + objEvent.size
next
next
SpamReport = SpamReport & "</table>" & vbcrlf
REm Email Bit
Set objEmail = CreateObject("CDO.Message")
objEmail.From = "spamreport@yourdomain.com.au"
objEmail.To = "youremail@yourdomain.com"
objEmail.Subject = "Spam Report for " & formatdatetime(now(),2) & " " &spamcount & " Mails Blocked " _
& (spambytes\1024) & " KB"
objEmail.htmlbody = SpamReport
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "YourServer"
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objEmail.Configuration.Fields.Update
objEmail.Send

Popular posts from this blog

The MailboxConcurrency limit and using Batching in the Microsoft Graph API

If your getting an error such as Application is over its MailboxConcurrency limit while using the Microsoft Graph API this post may help you understand why. Background   The Mailbox  concurrency limit when your using the Graph API is 4 as per https://docs.microsoft.com/en-us/graph/throttling#outlook-service-limits . This is evaluated for each app ID and mailbox combination so this means you can have different apps running under the same credentials and the poor behavior of one won't cause the other to be throttled. If you compared that to EWS you could have up to 27 concurrent connections but they are shared across all apps on a first come first served basis. Batching Batching in the Graph API is a way of combining multiple requests into a single HTTP request. Batching in the Exchange Mail API's EWS and MAPI has been around for a long time and its common, for email Apps to process large numbers of smaller items for a variety of reasons.  Batching in the Gr...
Read more

Exporting and Uploading Mailbox Items using Exchange Web Services using the new ExportItems and UploadItems operations in Exchange 2010 SP1

Two new EWS Operations ExportItems and UploadItems where introduced in Exchange 2010 SP1 that allowed you to do a number of useful things that where previously not possible using Exchange Web Services. Any object that Exchange stores is basically a collection of properties for example a message object is a collection of Message properties, Recipient properties and Attachment properties with a few meta properties that describe the underlying storage thrown in. Normally when using EWS you can access these properties in a number of a ways eg one example is using the strongly type objects such as emailmessage that presents the underlying properties in an intuitive way that's easy to use. Another way is using Extended Properties to access the underlying properties directly. However previously in EWS there was no method to access every property of a message hence there is no way to export or import an item and maintain full fidelity of every property on that item (you could export the...
Read more

EWS Create Mailbox folder Powershell module for Exchange and Office365 Mailboxes

This is a rollup post for a couple of scripts I've posted in the past for creating folders using EWS in an Exchange OnPremise or Exchange online Cloud mailbox. It can do the following Create a Folder in the Root of the Mailbox Create-Folder -Mailboxname mailbox@domain.com -NewFolderName test Create a Folder as a SubFolder of the Inbox Create-Folder -Mailboxname mailbox@domain.com -NewFolderName test -ParentFolder '\Inbox' Create a Folder as a SubFolder of the Inbox using EWS Impersonation Create-Folder -Mailboxname mailbox@domain.com -NewFolderName test -ParentFolder '\Inbox' -useImpersonation Create a new Contacts Folder as a SubFolder of the Mailboxes Contacts Folder Create-Folder -Mailboxname mailbox@domain.com -NewFolderName test -ParentFolder '\Contacts' -FolderClass IPF.Contact Create a new Calendar Folder as a SubFolder of the Mailboxes Calendar Folder Create-Folder -Mailboxname mailbox@domain.com -NewFolderName test -Parent...
Read more
All sample scripts and source code is provided by for illustrative purposes only. All examples are untested in different environments and therefore, I cannot guarantee or imply reliability, serviceability, or function of these programs.

All code contained herein is provided to you "AS IS" without any warranties of any kind. The implied warranties of non-infringement, merchantability and fitness for a particular purpose are expressly disclaimed.